Create Bundle

public static Map<String, String> createSABundle() {
    String apiVersion = '54.0'; // Spring '22
    String bundleApi = '/bundleflow/api/v1.0/bundle';
    String host = {Namespace}.BundleLogic.getBundlerFalconEnvironment();
    String ref = URL.getOrgDomainUrl().toExternalForm();

    String bundleService = host + bundleApi;
    
    // Create HTTP request
    HttpRequest request = new HttpRequest();
    request.setEndpoint(bundleService);
    request.setMethod('POST');
    request.setHeader('sf_api_version', apiVersion);
    request.setHeader('Content-Type', 'application/json' );
    // NOTE: This user must have 'Field Service Integration' permissions.
    request.setHeader('Authorization', 'Bearer ' + UserInfo.getSessionId()); 
    request.setHeader('Referer', ref);
    request.setHeader('x-sfdc-tenant-id', 'core/prod/ORG-ID_18_Characters');
    request.setTimeout(120000);
    
    // Create the body
    Map<String, Object> body = new Map<String, Object>();
    body.put('initiate','manual');
    body.put('bundlePolicyId','7sT9A0000004DX6UAM'); // NOTE: Use a real bundle policy ID.

    Map<String, Object> saList = new Map<String, Object>(); 
    saList.put('serviceAppointmentId', '08p9A0000005LEGQA2'); // NOTE: Use a real Service Appointment ID.
    saList.put('action', 'add');

    List<Object> objectsList =  new List<Object>();
    objectsList.add(saList);

    body.put('saRequestPayloads', objectsList);

    String reqBody = JSON.serialize(body);
    System.debug(body);
    request.setBody(reqBody);

    HttpResponse response = new Http().send(request);

    // Parse the JSON response
    
    // Handle a redirect message
    while (response.getStatusCode() == 302) {
        request.setEndpoint(response.getHeader('Location'));
        response = new Http().send(request);
    }

    Map<String, String> returnValue = new Map<String, String>();
    returnValue.put('statusCode', String.valueOf(response.getStatusCode()));

    // Return value when we don't get a success response
    if (response.getStatusCode() != 200) {
        returnValue.put('message', 'The status code returned was not expected: ' + response.getStatusCode() + ' ' + response.getStatus());
        System.debug(returnValue.get('message'));
        return (returnValue);
        
    // Return value when we do get a success response
    } else {
        returnValue.put('message', response.getBody());
        System.debug(response.getBody());
        return (returnValue);
    }
}

Map<String, String> response = createSABundle();
System.debug(response);