Apex スケジューラ

一定の間隔で実行されるように Apex クラスのスケジュールを設定するには、最初に Salesforce が提供するインターフェース Schedulable を実装する Apex クラスを記述します。

スケジューラは、システムとして実行されます。ユーザがそのクラスの実行権限を持っているかどうかにかかわらず、すべてのクラスが実行されます。

Salesforce ユーザインターフェースを使用してスケジュール済みの Apex ジョブの実行を監視および停止するには、[設定] から、[クイック検索] ボックスに「スケジュール済みジョブ」と入力し、[スケジュール済みジョブ] を選択します。

1global void execute(SchedulableContext sc){}

実装されたメソッドは global または public として宣言する必要があります。

次の例では、mergeNumbers と呼ばれるクラスの Schedulable インターフェースを実装します。

1global class scheduledMerge implements Schedulable {
2   global void execute(SchedulableContext SC) {
3      mergeNumbers M = new mergeNumbers(); 
4   }
5}

次の例では、上記のクラスを実装するための System.Schedule メソッドを使用します。

1scheduledMerge m = new scheduledMerge();
2String sch = '20 30 8 10 2 ?';
3String jobID = system.schedule('Merge Job', sch, m);

Apex の一括処理クラスで Schedulable インターフェースを使用することもできます。次の例では、batchable と呼ばれる Apex の一括処理クラスの Schedulable インターフェースを実装します。

1global class scheduledBatchable implements Schedulable {
2   global void execute(SchedulableContext sc) {
3      batchable b = new batchable(); 
4      database.executebatch(b);
5   }
6}

一括処理ジョブをスケジュールする簡単な方法は、System.scheduleBatch メソッドをコールすることです。この際、Schedulable インターフェースを実装する必要はありません。

スケジュール済みジョブを追跡するには、SchedulableContext オブジェクトを使用します。SchedulableContext getTriggerID メソッドは、このスケジュール済みジョブに関連付けられている CronTrigger オブジェクトの ID を文字列として返します。CronTrigger を照会すると、スケジュール済みジョブの進行状況を追跡できます。

スケジュール済みジョブの実行を停止するには、getTriggerID メソッドによって返された ID と共に System.abortJob メソッドを使用します。

次に、Apex スケジューラを使用したテスト方法の例を示します。

System.schedule メソッドは、匿名プロセスを開始します。つまり、スケジュールされた Apex をテストするとき、結果に対してテストする前にスケジュール済みジョブが終了している必要があります。System.schedule メソッドを実行する前後で、テストメソッド startTest と stopTest を使用して、テストを続行する前にスケジュール済みジョブが終了するようにします。startTest メソッドの後に実行されたすべての非同期コールはシステムによって収集されます。stopTest を実行する場合、すべての非同期プロセスが同期して実行されます。startTest メソッドと stopTest メソッド内に System.schedule メソッドを含めない場合、スケジュール済みジョブは Salesforce API バージョン 25.0 以降で保存された Apex のテストメソッドでは最後に実行されますが、それよりも前のバージョンでは実行されません。

1global class TestScheduledApexFromTestMethod implements Schedulable {
2
3// This test runs a scheduled job at midnight Sept. 3rd. 2022
4
5   public static String CRON_EXP = '0 0 0 3 9 ? 2022';
6   
7   global void execute(SchedulableContext ctx) {
8      CronTrigger ct = [SELECT Id, CronExpression, TimesTriggered, NextFireTime
9                FROM CronTrigger WHERE Id = :ctx.getTriggerId()];
10
11      System.assertEquals(CRON_EXP, ct.CronExpression);
12      System.assertEquals(0, ct.TimesTriggered);
13      System.assertEquals('2022-09-03 00:00:00', String.valueOf(ct.NextFireTime));
14
15      Account a = [SELECT Id, Name FROM Account WHERE Name = 
16                  'testScheduledApexFromTestMethod'];
17      a.name = 'testScheduledApexFromTestMethodUpdated';
18      update a;
19   }   
20}

1@istest
2class TestClass {
3
4   static testmethod void test() {
5   Test.startTest();
6
7      Account a = new Account();
8      a.Name = 'testScheduledApexFromTestMethod';
9      insert a;
10
11      // Schedule the test job
12
13      String jobId = System.schedule('testBasicScheduledApex',
14      TestScheduledApexFromTestMethod.CRON_EXP, 
15         new TestScheduledApexFromTestMethod());
16
17      // Get the information from the CronTrigger API object
18      CronTrigger ct = [SELECT Id, CronExpression, TimesTriggered, 
19         NextFireTime
20         FROM CronTrigger WHERE id = :jobId];
21
22      // Verify the expressions are the same
23      System.assertEquals(TestScheduledApexFromTestMethod.CRON_EXP, 
24         ct.CronExpression);
25
26      // Verify the job has not run
27      System.assertEquals(0, ct.TimesTriggered);
28
29      // Verify the next time the job will run
30      System.assertEquals('2022-09-03 00:00:00', 
31         String.valueOf(ct.NextFireTime));
32      System.assertNotEquals('testScheduledApexFromTestMethodUpdated',
33         [SELECT id, name FROM account WHERE id = :a.id].name);
34
35   Test.stopTest();
36
37   System.assertEquals('testScheduledApexFromTestMethodUpdated',
38   [SELECT Id, Name FROM Account WHERE Id = :a.Id].Name);
39
40   }
41}

• Salesforce は、指定された時間に実行されるようにクラスをスケジュール設定します。実際の実行は、サービスの使用可能状態に応じて遅れる場合があります。
• クラスをトリガからスケジュールする場合は、細心の注意を払ってください。制限を超えるスケジュールクラスをトリガで追加しないようにする必要があります。特に、API の一括更新、インポートウィザード、ユーザインターフェースを使用したレコードの一括変更、および複数のレコードを一度に更新するすべての処理については十分に考慮してください。
• execute メソッドで追加処理を行うことはできますが、すべての処理が個別のクラスで行われるようにすることをお勧めします。
• 同期 Web サービスコールアウトは、スケジュールされた Apex からは実行できません。コールアウトを実行するには、@future(callout=true) のアノテーションを付加したメソッドにコールアウトを配置し、このメソッドをスケジュールされた Apex からコールすることで非同期コールアウトを実行します。ただし、スケジュールされた Apex で一括処理ジョブを実行する場合、一括処理クラスからコールアウトを実行できます。「Apex の一括処理の使用」を参照してください。
• Salesforce のサービスメンテナンスによるダウンタイム中に実行がスケジュールされている Apex ジョブは、サービスが再開され、システムリソースが使用可能になったときに実行されるようにスケジュールされます。ダウンタイムの発生時にスケジュール済みの Apex ジョブが実行されていた場合は、ジョブがロールバックされ、サービス再開後に再度スケジュールされます。サービスのメジャーアップグレードの後は、システムの使用率が急増するため、スケジュール済みの Apex ジョブの開始が通常より遅れる可能性があります。