Hi Mike.

I saw your post, and had a small sample that I use to demo this kind of functionality to my students when I teach Visualforce.  Though you already have a solution, I thought you might find it useful so will post below.

Here's the page, similar to yours except it uses the Visualforce PageBlockTable to automatically iterate the list and generate an HTML table, instead of having to use a Repeat component.

It also demonstrates loading the list from a command button using Ajax to call the controller's action method, and does a partial rerender of just the output panel containing the table.  

When the form first loads, it doesn't show any data, but refreshes the list upon clicking the button. 

<!--
name        : VFDemo_LoadList
author      : Don Robins (www.outformations.com)
date        : 11th February, 2011
description : Demo page to show drag drop in action
-->
<apex:page controller="VFDemo_LoadListController" showHeader="false" sidebar="false" >
    <apex:sectionHeader title="List Demo Page" subtitle="Load a list of Accounts"/>
    <apex:form >
        <apex:commandButton action="{!refreshList}" value="Click To Reload the List" reRender="listArea" id="btnLoad" /><br/>
    </apex:form> 

    <apex:outputPanel id="listArea">
        <apex:pageBlock title="Short List Of Accounts">
            <apex:pageBlockTable value="{!accountList}" var="a">
                <apex:column value="{!a.id}"/> 
                <apex:column value="{!a.name}"/> 
            </apex:pageBlockTable> 
        </apex:pageBlock>
    </apex:outputPanel>    
</apex:page>

Here's the controller code; note that there are numerous places where you could load the list from when the page first loads, including the constructor (the solution cited above), or something called a static initializer which fires before the constructor, or in the get{}; accessor if you were to use a public property rather than a public getter method for the list. You could of course also put the same logic in the getter method too.

You'll see that a call to the private buildList() method can be wrapped in the public action method refreshList(); this is the action method bound to the CommandButton on the view, and it returns a null PageReference object so that navigation returns to the same view when called. It's job is simply to perform the partial rerender of the outputPanel content.

/**
name        : LoadListController
author      : Don Robins (www.outformations.com)
date        : 11th February, 2011
description : Controller to drive a demo load list page
note        : Note that WITH SHARING is not active
*/
public class VFDemo_LoadListController{

    //Private member variable scoped only within the constructor, 
    //exposed through the public getter method or public property. 
    private List<Account> accounts = new List <Account>();

    //static{
    //    buildList();
    //}

    //Default constructor
    public VFDemo_LoadListController(){
        //You can load the lists in the constructor so the are preloaded when the page inits.		
        //buildList();
    }

    //Getter method to return a populated list from the private member variable. 
    public List<Account> getAccountList(){
        //Assumed to be loaded.
        return accounts;
    }

    //The getter method above could be replaced with a public readonly property instead, 
    //public List<Account> AccountList{
    //    get{
    //        //Calls the buildList() method if the private member variable is not yet loaded.
    //        if (accounts == null)
    //		{
    //            buildList();
    //        }
    //        //Else returns the populated list.
    //        return accounts;
    //    }
    //}
	 
    //Action method called from view.
    public pagereference refreshList(){
        buildList();
        //Return null to stay on same page.
        return null;
    }

    //Here's the private method used to load the list; 
    //could be called from constructor or action method
    private void buildList()
    {           
        accounts = [ SELECT Id, Name FROM Account LIMIT 10 ];          
    }	    

    //Don't forget to build your tests, and they should include some real asserts!
    @istest
    private static void testthis(){
        VFDemo_LoadListController cont = new VFDemo_LoadListController();
        cont.getAccountList();    
        cont.refreshList();    
    }
}

And finally there's a simple unit test; it's a great practice to get in the habit of writing your unit test code as you build your classes so you don't have to worry about them later.

Hope this helps explain a few more of the potential moving parts of the Visualforce framework.

Regards,

Don