Newer Version Available

This content describes an older version of this product. View Latest

Common Date Formulas

Available in: All Editions

Watch a Demo: How to Calculate the Number of Days a Case is Open

Finding the Day, Month, or Year from a Date

Use the functions DAY( date ), MONTH( date ), and YEAR( date ) to return their respective numerical values. Replace date with a value of type Date (e.g. TODAY()).

To use these functions with Date/Time values, first convert them to a date with the DATEVALUE() function. For example, DAY( DATEVALUE( date/time )).

Finding Out if a Year Is a Leap Year

This formula determines whether or not a year is a leap year. A year is only a leap year if it’s divisible by 400, or if it’s divisible by four but NOT by 100.

1OR( 
2  MOD( YEAR( date ), 400 ) = 0, 
3  AND( 
4   MOD( YEAR( date ), 4 ) = 0,
5    MOD( YEAR( date ), 100 ) != 0
6  )
7)

Finding Which Quarter a Date Is In

For standard quarters, you can determine which quarter a date falls in using this formula. This formula returns the number of the quarter in which date falls (1–4) by dividing the current month by three (the number of months in each quarter) and taking the ceiling.

1CEILING( MONTH ( date ) / 3 )

The formula for shifted quarters is similar, but shifts the month of the date by the number of months between January and the first quarter of the fiscal year. The example below illustrates how you can find a date’s quarter if Q1 starts in February instead of January.

1CEILING( ( MONTH ( date ) - 1 ) / 3)

If you want to check whether a date is in the current quarter, add a check to compare the date’s year and quarter with TODAY()’s year and quarter.

1AND(
2   CEILING( MONTH( date ) / 3 ) = CEILING( MONTH( TODAY() ) / 3 ),
3   YEAR( date ) = YEAR( TODAY() )
4)

Finding the Week of the Year a Date Is In

To find the number of a date’s week of the year, use this formula:

1IF( 
2  CEILING( ( date - DATE( YEAR( date ), 1, 1) + 1) / 7) > 52,
3  52,
4  CEILING( ( date - DATE( YEAR( date ), 1, 1) + 1) / 7)
5)

You can find the current week by determining how many days there have been in the current year and dividing that value by 7. The IF() statement ensures that the week number the formula returns doesn’t exceed 52. So if the given date is December 31 of the given year, the formula returns 52, even though it’s more than 52 weeks after the week of January.

Finding Whether Two Dates Are in the Same Month

To determine whether two Dates fall in the same month, say for a validation rule to determine whether an opportunity Close Date is in the current month, use this formula:

1AND(
2  MONTH( date_1 ) == MONTH( date_2 ),
3  YEAR( date_1 ) == YEAR( date_2 )
4)

Finding the Last Day of the Month

The easiest way to find the last day of a month is to find the first day of the next month and subtract a day.

1IF(
2  MONTH( date ) = 12,
3  DATE( YEAR( date ), 12, 31 ),
4  DATE( YEAR( date ), MONTH ( date ) + 1, 1 ) - 1 
5)

Displaying the Month as a String Instead of a Number

To return the month as a text string instead of a number, use:

1CASE(
2  MONTH( date ),
3  1, "January",
4  2, "February",
5  3, "March",
6  4, "April",
7  5, "May",
8  6, "June",
9  7, "July",
10  8, "August",
11  9, "September",
12  10, "October",
13  11, "November",
14  "December",
15)

If your organization uses multiple languages, you can replace the names of the month with a custom label:

1CASE(
2  MONTH( date ),
3  1, $Label.Month_of_Year_1,
4  2, $Label.Month_of_Year_2,
5  3, $Label.Month_of_Year_3,
6  4, $Label.Month_of_Year_4,
7  5, $Label.Month_of_Year_5,
8  6, $Label.Month_of_Year_6,
9  7, $Label.Month_of_Year_7,
10  8, $Label.Month_of_Year_8,
11  9, $Label.Month_of_Year_9,
12  10, $Label.Month_of_Year_10,
13  11, $Label.Month_of_Year_11,
14  $Label.Month_of_Year_12
15)

Finding and Displaying the Day of the Week From a Date

To find the day of the week from a Date value, use a known Sunday (e.g. January 7, 1900) and subtract it from the date (e.g. TODAY()) to get the difference in days. The MOD() function finds the remainder of this result when divided by 7 to give the numerical value of the day of the week between 0 (Sunday) and 6 (Saturday). The formula below finds the result and then returns the text name of that day.

1CASE(
2  MOD( date - DATE( 1900, 1, 7 ), 7 ),
3  0, "Sunday",
4  1, "Monday",
5  2, "Tuesday",
6  3, "Wednesday",
7  4, "Thursday",
8  5, "Friday", 
9  "Saturday"
10)

Note that this formula only works for dates after 01/07/1900. If you’re working with older dates, use the same process with any Sunday prior to your earliest date (e.g. 01/05/1800).

You can also adjust this formula if your week starts on a different day. For example, if your week starts on Monday, you can use January 8, 1900 in your condition. The new formula looks like this:

1CASE(
2  MOD( date - DATE( 1900, 1, 8 ), 7 ),
3  0, "Monday",
4  1, "Tuesday",
5  2, "Wednesday",
6  3, "Thursday",
7  4, "Friday",
8  5, "Saturday", 
9  "Sunday"
10)

Like the formula for getting the name of the month, if your organization uses multiple languages, you can replace the names of the day of the week with a variable like $Label.Day_of_Week_1, etc.

Finding the Next Day of the Week After a Date

To find the date of the next occurrence of a particular day of the week following a given Date, get the difference in the number of days of the week between a date and a day_of_week, a number 0–6 where 0 = Sunday and 6 = Saturday. By adding this difference to the current date, you’ll find the date of the day_of_week. The IF() statement in this formula handles cases where the day_of_week is prior to the day of the week of the date value (e.g. date is a Thursday and day_of_week is a Monday) by adding 7 to the difference.

1date + ( day_of_week - MOD( date - DATE( 1900, 1, 7 ), 7 ) )
2+
3IF( 
4  MOD( date - DATE( 1900, 1, 7 ), 7 ) >= day_of_week,
5  7,
6  0
7)

You can substitute either a constant or another field in for the day_of_week value based on your needs.

Finding the Number of Days Between Two Dates

To find the number of days between two dates, date_1 and date_2, subtract the earlier date from the later date: date_1 — date_2

You can alter this slightly if you want to determine a date a certain number of days in the past. For example, say you want a formula to return true if some date field is more than 30 days prior to the current date and false otherwise. This formula does just that:

1TODAY() - 30 > date

Finding the Number of Business Days Between Two Dates

Calculating how many business days passed between two dates is slightly more complex than calculating total elapsed days. The basic strategy is to choose a reference Monday from the past and find out how many full weeks and any additional portion of a week have passed between the reference date and the date you’re examining. These values are multiplied by five (for a five-day work week) and then the difference between them is taken to calculate business days.

1(5 * ( FLOOR( ( date_1 - DATE( 1900, 1, 8) ) / 7 ) ) + MIN( 5, MOD( date_1 - DATE( 1900, 1, 8), 7 ) ) )
2-
3(5 * ( FLOOR( ( date_2 - DATE( 1900, 1, 8) ) / 7 ) ) + MIN( 5, MOD( date_2 - DATE( 1900, 1, 8), 7 ) ) )

In this formula, date_1 is the more recent date and date_2 is the earlier date. If your work week runs shorter or longer than five days, replace all fives in the formula with the length of your week.

Adding Days, Months, and Years to a Date

If you want to add a certain number of days to a date, add that number to the date directly. For example, to add five days to a date, the formula is date + 5.

Adding years to a date is fairly simple, but you do need to check that the future date is valid. That is, adding five years to February 29 (a leap year) results in an invalid date. The following formula adds num_years to date by checking if the date is February 29 and if the future date is not in a leap year. If these conditions hold true, the formula returns March 1 in the future year. Otherwise, the formula sets the Date to the same month and day num_years in the future.

1IF(
2  AND(
3    MONTH( date ) = 2,
4    DAY( date ) = 29,
5    NOT( 
6      OR( 
7        MOD( YEAR( date ), 400 ) = 0, 
8        AND( 
9          MOD( YEAR( date ), 4 ) = 0,
10          MOD( YEAR( date ), 100 ) != 0
11        )
12      )
13    ) 
14  ),
15  DATE( YEAR( date ) + num_years, 3, 1)
16  DATE( YEAR( date ) + num_years, MONTH( date ), DAY( date ) )
17)

Adding months to a date is slightly more complicated as months vary in length and the cycle of months restart with each year. Therefore, a valid day in one month (January 31) might not be valid in another month (February 31). A simple solution is to approximate each month’s length as 365/12 days:

1date + ( ( 365 / 12 ) * Number_months )

While this formula is a good estimate, it doesn’t return an exact date. For example, if you add two months to April 30 using this method, the formula will return June 29 instead of June 30. Returning an exact date depends on your organization’s preference. For example, when you add one month to January 31, should it return February 28 (the last day of the next month) or March 2 (30 days after January 31)?

This formula does the following:

Returns March 1 if the future month is a February and the day is greater than 28. This portion of the formula performs the same for both leap and non-leap years.
Returns the first day of the next month if the future month is April, June, September, or November and the day is greater than 30.
Otherwise, it returns the correct date in the future month.

This example formula adds two months to a given date. You can modify the conditions on this formula if you prefer different behaviors for dates at the end of the month.

1IF( 
2  MOD( MONTH( date ) + 2, 12 ) = 2,
3  IF( 
4    DAY( date ) > 28, 
5    DATE( YEAR( date ) + FLOOR( ( MONTH( date ) + 2 ) / 12 ), 3, 1 ),
6    DATE( YEAR( date ) + FLOOR( ( MONTH( date ) + 2 ) / 12 ), 2, DAY( date ) ) 
7  ),
8  IF(
9    OR( 
10      MOD( MONTH( date ) + 2, 12 ) = 4,
11      MOD( MONTH( date ) + 2, 12 ) = 6,
12      MOD( MONTH( date ) + 2, 12 ) = 9,
13      MOD( MONTH( date ) + 2, 12 ) = 11
14    ),
15    IF( 
16      DAY( date ) > 30, 
17      DATE( YEAR( date ) + FLOOR( ( MONTH(  date  ) + 2 ) / 12 ), 
18       MOD( MONTH( date ) + 2, 12 ) + 1, 1 ),
19      DATE( YEAR( date ) + FLOOR( ( MONTH( date ) + 2 ) / 12 ),
20       MOD( MONTH( date ) + 2, 12), DAY( date ) ) 
21    ),
22    IF( 
23      MOD( MONTH( date ) + 2, 12 ) = 0,
24      DATE( YEAR( date ) + FLOOR( ( MONTH( date ) + 2 ) / 12 ) - 1, 12, DAY( date ) ),
25      DATE( YEAR( date ) + FLOOR( ( MONTH( date ) + 2 ) / 12 ), 
26       MOD( MONTH( date ) + 2, 12), DAY( date ) )
27    )
28  )
29)

If you’re using these formulas for expiration dates, you might want to subtract a day from the return value to make sure that some action is completed before the calculated date.

Adding Business Days to a Date

This formula finds three business days from a given date.

1CASE( 
2  MOD( date - DATE( 1900, 1, 7 ), 7 ),
3  3, date + 2 + 3,
4  4, date + 2 + 3,
5  5, date + 2 + 3,
6  6, date + 1 + 3,
7  date + 3
8)

This formula finds the day of the week of the date field value. If the date is a Wednesday, Thursday, or Friday, the formula adds five calendar days (two weekend days, three week days) to the date to account for the weekend. If date is a Saturday, you need four additional calendar days. For any other day of the week (Sunday — Tuesday), simply add three days. You can easily modify this formula to add more or less business days. The tip for getting the day of the week might be useful if you need to adjust this formula.

Finding the Hour, Minute, or Second from a Date/Time

To get the hour, minute, and second from a Date/Time field as a numerical value, use the following formulas where TZoffset is the difference between the user’s time zone and GMT. For hour in 24–hour format:

1VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) )

For hour in 12–hour format:

1IF(
2  OR(
3    VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) ) = 0,
4    VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) ) = 12
5  ),
6  12,
7  VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) ) 
8   - 
9   IF( 
10     VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) ) < 12, 
11     0, 
12     12 
13   )
14)

For minutes:

1VALUE( MID( TEXT( date/time - TZoffset ), 15, 2 ) )

For seconds:

1VALUE( MID( TEXT( date/time - TZoffset ), 18, 2 ) )

And, to get “AM”. or “PM” as a string, use:

1IF(
2  VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) ) < 12,
3  "AM",
4  "PM"
5)

To return the time as a string in “HH:MM:SS A/PM” format, use the following formula:

1IF(
2  OR(
3    VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) ) = 0,
4    VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) ) = 12
5  ),
6  "12",
7  TEXT( VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) ) 
8   -
9   IF( 
10     VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) ) < 12, 
11     0, 
12     12 
13   ) 
14  )
15)
16& ":" &
17MID( TEXT( date/time - TZoffset ), 15, 2 )
18& ":" &
19MID( TEXT( date/time - TZoffset ), 18, 2 )
20& " " &
21IF(
22  VALUE( MID( TEXT( date/time - TZoffset ), 12, 2 ) ) < 12,
23  "AM",
24  "PM"
25)

When working with time in formula fields, you need to consider the time difference between your organization and GMT. See A Note About Date/Time and Time Zones for help understanding the time zone offset used in this formula.

Finding the Elapsed Time Between Date/Times

To find the difference between two Date values, subtract one from the other like so: date_1 — date_2 to return the difference in days.

Finding the elapsed time between two Date/Time values is slightly more complex. For simplicity, the custom field Diff_c refers to the difference between two Date/Time values. Since Diff_c is a number, you can use this formula to convert it to days, hours, and minutes.

1IF(
2  Diff_c > 0 ,
3  TEXT( FLOOR( Diff_c ) ) & " days "
4  & TEXT( FLOOR( MOD( Diff_c * 24, 24 ) ) ) & " hours "
5  & TEXT( ROUND( MOD( Diff_c * 24 * 60, 60 ), 0 ) ) & " minutes",
6  ""
7)

Finding the Number of Business Hours Between Two Date/Times

The formula for finding business hours between two Date/Time values expands on the formula for finding elapsed business days. It works on the same principle of using a reference Date/Time, in this case 1/8/1900 at 16:00 GMT (9 a.m. PDT), and then finding your Dates’ respective distances from that reference. The formula rounds the value it finds to the nearest hour and assumes an 8–hour, 9 a.m. – 5 p.m. work day.

1ROUND( 8 * (
2   ( 5 * FLOOR( ( date/time_1 - DATE( 1900, 1, 8) ) / 7) +
3    MIN(5, 
4     MOD( date/time_1 - DATE( 1900, 1, 8), 7) +
5     MIN( 1, 24 / 8 * ( MOD( date/time_1 - DATETIMEVALUE( '1900-01-08 16:00:00' ), 1 ) ) )
6    ) 
7   )
8 -
9   ( 5 * FLOOR( ( DATEVALUE( date/time_2 ) - DATE( 1900, 1, 8) ) / 7) +
10     MIN( 5,
11      MOD( DATEVALUE( date/time_2 ) - DATE( 1996, 1, 1), 7 ) +
12      MIN( 1, 24 / 8 * ( MOD( date/time_2 - DATETIMEVALUE( '1900-01-08 16:00:00' ), 1) ) )
13    )
14   ) 
15  ), 
160 )

You can change the eights in the formula to account for a longer or shorter work day. If you live in a different time zone or your work day doesn’t start at 9:00 a.m., change the reference time to the start of your work day in GMT. See A Note About Date/Time and Time Zones for more information.

Useful Formula Fields

No Results