DuplicateResult Class

1public class ContactDedupeController {
2    
3    // Initialize a variable to hold the contact record you're processing
4    private final Contact contact;
5    
6    // Initialize a list to hold any duplicate records
7    private List<sObject> duplicateRecords;
8    
9    // Define variable that’s true if there are duplicate records
10    public boolean hasDuplicateResult{get;set;}
11    
12    // Define the constructor
13    public ContactDedupeController() {
14        
15        // Define the values for the contact you’re processing based on its ID
16        Id id = ApexPages.currentPage().getParameters().get('id');
17        this.contact = (id == null) ? new Contact() : 
18            [SELECT Id, FirstName, LastName, Email, Phone, AccountId 
19             FROM Contact WHERE Id = :id];
20       
21        // Initialize empty list of potential duplicate records
22        this.duplicateRecords = new List<sObject>();
23        this.hasDuplicateResult = false;
24    }
25    
26    // Return contact and its values to the Visualforce page for display
27    public Contact getContact() {
28        return this.contact;
29    }
30    
31    // Return duplicate records to the Visualforce page for display
32    public List<sObject> getDuplicateRecords() {
33        return this.duplicateRecords;
34    }
35    
36    // Process the saved record and handle any duplicates
37    public PageReference save() {
38        
39        // Optionally, set DML options here, use “DML” instead of “false” 
40        //   in the insert()
41        // Database.DMLOptions dml = new Database.DMLOptions(); 
42        // dml.DuplicateRuleHeader.allowSave = true;
43        // dml.DuplicateRuleHeader.includeRecordDetails = true;
44        // dml.DuplicateRuleHeader.runsAsCurrentUser = true;
45        Database.SaveResult saveResult = Database.insert(contact, false);
46
47        if (!saveResult.isSuccess()) {
48            for (Database.Error error : saveResult.getErrors()) {
49                // If there are duplicates, an error occurs
50                // Process only duplicates and not other errors 
51                //   (e.g., validation errors)
52                if (error instanceof Database.DuplicateError) {
53                    // Handle the duplicate error by first casting it as a 
54                    //   DuplicateError class
55                    // This lets you use methods of that class 
56                    //  (e.g., getDuplicateResult())
57                    Database.DuplicateError duplicateError = 
58                            (Database.DuplicateError)error;
59                    Datacloud.DuplicateResult duplicateResult = 
60                            duplicateError.getDuplicateResult();
61                    
62                    // Display duplicate error message as defined in the duplicate rule
63                    ApexPages.Message errorMessage = new ApexPages.Message(
64                            ApexPages.Severity.ERROR, 'Duplicate Error: ' + 
65                            duplicateResult.getErrorMessage());
66                    ApexPages.addMessage(errorMessage);
67                    
68                    // Get duplicate records
69                    this.duplicateRecords = new List<sObject>();
70
71                    // Return only match results of matching rules that 
72                    //  find duplicate records
73                    Datacloud.MatchResult[] matchResults = 
74                            duplicateResult.getMatchResults();
75
76                    // Just grab first match result (which contains the 
77                    //   duplicate record found and other match info)
78                    Datacloud.MatchResult matchResult = matchResults[0];
79
80                    Datacloud.MatchRecord[] matchRecords = matchResult.getMatchRecords();
81
82                    // Add matched record to the duplicate records variable
83                    for (Datacloud.MatchRecord matchRecord : matchRecords) {
84                        System.debug('MatchRecord: ' + matchRecord.getRecord());
85                        this.duplicateRecords.add(matchRecord.getRecord());
86                    }
87                    this.hasDuplicateResult = !this.duplicateRecords.isEmpty();
88                }
89            }
90            
91            //If there’s a duplicate record, stay on the page
92            return null;
93        }
94        
95        //  After save, navigate to the view page:
96        return (new ApexPages.StandardController(contact)).view();
97    }
98    
99}