Note: This release is in preview. Features described here don’t become generally available until the latest general availability date that Salesforce announces for this release. Before then, and where features are noted as beta, pilot, or developer preview, we can’t guarantee general availability within any particular time frame or at all. Make your purchase decisions only on the basis of generally available products and features.

FieldSet Class

Contains methods for discovering and retrieving the details of field sets created on sObjects.

Namespace

Schema

Usage

Use the methods in the Schema.FieldSet class to discover the fields contained within a field set, and get details about the field set itself, such as the name, namespace, label, and so on. The following example shows how to get a collection of field set describe result objects for an sObject. The key of the returned Map is the field set name, and the value is the corresponding field set describe result.

1Map<String, Schema.FieldSet> FsMap = 
2    Schema.SObjectType.Account.fieldSets.getMap();

Field sets are also available from sObject describe results. The following lines of code are equivalent to the prior sample:

1Schema.DescribeSObjectResult d = 
2  Account.sObjectType.getDescribe();
3Map<String, Schema.FieldSet> FsMap = 
4  d.fieldSets.getMap();

To work with an individual field set, you can access it via the map of field sets on an sObject or, when you know the name of the field set in advance, using an explicit reference to the field set. The following two lines of code retrieve the same field set:

1Schema.FieldSet fs1 = Schema.SObjectType.Account.fieldSets.getMap().get('field_set_name');
2Schema.FieldSet fs2 = Schema.SObjectType.Account.fieldSets.field_set_name;

Example: Displaying a Field Set on a Visualforce Page

This sample uses Schema.FieldSet and Schema.FieldSetMember methods to dynamically get all the fields in the Dimensions field set for the Merchandise custom object. The list of fields is then used to construct a SOQL query that ensures those fields are available for display. The Visualforce page uses the MerchandiseDetails class as its controller.

1public with sharing class MerchandiseDetails {
2
3    public Merchandise__c merch { get; set; }
4    
5    public MerchandiseDetails() {
6        this.merch = getMerchandise();
7    }
8
9    public List<Schema.FieldSetMember> getFields() {
10        return SObjectType.Merchandise__c.FieldSets.Dimensions.getFields();
11    }
12
13    private Merchandise__c getMerchandise() {
14        String query = 'SELECT ';
15        for(Schema.FieldSetMember f : this.getFields()) {
16            query += f.getFieldPath() + ', ';
17        }
18        query += 'Id, Name FROM Merchandise__c LIMIT 1';
19        return Database.query(query, AccessLevel.USER_MODE);
20    }
21}

The Visualforce page using the above controller is simple:

1<apex:page controller="MerchandiseDetails">
2    <apex:form >
3
4      <apex:pageBlock title="Product Details">
5          <apex:pageBlockSection title="Product">
6              <apex:inputField value="{!merch.Name}"/>
7          </apex:pageBlockSection>
8      
9          <apex:pageBlockSection title="Dimensions">
10              <apex:repeat value="{!fields}" var="f">
11                  <apex:inputField value="{!merch[f.fieldPath]}" 
12                      required="{!OR(f.required, f.dbrequired)}"/>
13              </apex:repeat>
14          </apex:pageBlockSection>
15  
16        </apex:pageBlock>
17
18    </apex:form>  
19</apex:page>

One thing to note about the above markup is the expression used to determine if a field on the form should be indicated as being a required field. A field in a field set can be required by either the field set definition, or the field’s own definition. The expression handles both cases.

FieldSet Methods

The following are methods for FieldSet. All are instance methods.

getDescription()

Returns the field set’s description.

Signature

public String getDescription()

Return Value

Type: String

Usage

Description is a required field for a field set, intended to describe the context and content of the field set. It’s often intended for administrators who might be configuring a field set defined in a managed package, rather than for end users.

getFields()

Returns a list of Schema.FieldSetMember objects for the fields making up the field set.

Signature

public List<FieldSetMember> getFields()

Return Value

Type: List<Schema.FieldSetMember>

getLabel()

Returns the translation of the text label that is displayed next to the field in the Salesforce user interface.

Signature

public String getLabel()

Return Value

Type: String

getName()

Returns the field set’s name.

Signature

public String getName()

Return Value

Type: String

getNamespace()

Returns the field set’s namespace.

Signature

public String getNamespace()

Return Value

Type: String

Usage

The returned namespace is an empty string if your organization hasn’t set a namespace, and the field set is defined in your organization. Otherwise, it’s the namespace of your organization, or the namespace of the managed package containing the field set.

getSObjectType()

Returns the Schema.sObjectType of the sObject containing the field set definition.

Signature

public Schema.SObjectType getSObjectType()

Return Value

Type: Schema.SObjectType

Apex Reference Guide

FieldSet Class

Namespace

Usage

Example: Displaying a Field Set on a Visualforce Page

FieldSet Methods

getDescription()

Signature

Return Value

Usage

getFields()

Signature

Return Value

getLabel()

Signature

Return Value

getName()

Signature

Return Value

getNamespace()

Signature

Return Value

Usage

getSObjectType()

Signature

Return Value