sObject のリストの並び替え

List.sort メソッドを使用して、sObject のリストを並び替えることができます。

sObject の場合、並び替えは昇順で、次のセクションで説明する一連の比較ステップを使用します。または、「sObject のカスタム並び替え順」に示されるように、sObject を Apex クラスでラップして Comparable インターフェースを実装することで、sObject のカスタム並び替え順を実装することもできます。

sObject のデフォルトの並び替え順

List.sort メソッドは sObject を昇順で並び替え、一連の順序付けられたステップに従って sObject を比較します。これらのステップには比較に使用される表示ラベルまたは項目が規定されています。比較は最初のステップから開始され、規定の表示ラベルまたは項目を使用して 2 つの sObject が並び替えられたときに終了します。使用される比較の順序は次のようになります。

sObject 型の表示ラベル。
たとえば、Account sObject は Contact の前になります。
Name 項目 (該当する場合)。
たとえば、リストに A と B という名前の 2 つの取引先がある場合、取引先 A が取引先 B よりも前になります。
標準項目。ID 項目と Name 項目を除き、アルファベット順で最初の項目から使用されます。
たとえば、2 つの取引先が同じ名前の場合、並び替えに使用される最初の標準項目は AccountNumber です。
カスタム項目。アルファベット順で最初の項目から使用されます。
たとえば、2 つの取引先の名前と標準項目が同じで、FieldA と FieldB という 2 つのカスタム項目がある場合、並び替えでは FieldA の値が最初に使用されます。

この一連のすべてのステップが実行されるとは限りません。たとえば、リストに同じ種別で一意の Name 値がある 2 つの sObject が含まれる場合、これらは Name 項目に基づいて並び替えられ、並び替えはステップ 2 で停止します。別の例で、名前が同じか sObject に Name 項目がない場合、並び替えはステップ 3 まで進み、標準項目を基準に並び替えられます。

テキスト項目の場合、並び替えアルゴリズムは Unicode 並び替え順を使用します。また、空の項目は並び替え順で空でない項目より前になります。

次の例は、Account sObject のリストの並び替えです。この例では、Name 項目が使用されて、リスト内で Acme 取引先が 2 つの sForce 取引先より前に配置されることを示します。sForce という名前の取引先が 2 つあり、アルファベット順で Industry 項目は Site 項目より前になるため、Industry 項目が残りの取引先の並び替えに使用されます。

1swfobject.registerObject("clippy.codeblock-0", "9");
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17Account[] acctList = new List<Account>();        
18acctList.add( new Account(
19    Name='sForce',
20    Industry='Biotechnology',
21    Site='Austin'));
22acctList.add(new Account(
23    Name='sForce',
24    Industry='Agriculture',
25    Site='New York'));
26acctList.add(new Account(
27    Name='Acme'));
28System.debug(acctList);
29
30acctList.sort();
31System.assertEquals('Acme', acctList[0].Name);
32System.assertEquals('sForce', acctList[1].Name);
33System.assertEquals('Agriculture', acctList[1].Industry);
34System.assertEquals('sForce', acctList[2].Name);
35System.assertEquals('Biotechnology', acctList[2].Industry);
36System.debug(acctList);

次の例は前の例と同様ですが、Merchandise__c カスタムオブジェクトを使用する点が異なります。この例では、Name 項目が使用されて、リスト内で Notebooks 商品が Pens より前に配置されることを示します。Name 項目値が Pens の商品 sObject が 2 つあり、アルファベット順で Description 項目は Price および Total_Inventory 項目より前になるため、Description 項目が残りの商品品目の並び替えに使用されます。

1swfobject.registerObject("clippy.codeblock-1", "9");
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17Merchandise__c[] merchList = new List<Merchandise__c>();        
18merchList.add( new Merchandise__c(
19    Name='Pens',
20    Description__c='Red pens',
21    Price__c=2,
22    Total_Inventory__c=1000));
23merchList.add( new Merchandise__c(
24    Name='Notebooks',
25    Description__c='Cool notebooks',
26    Price__c=3.50,
27    Total_Inventory__c=2000));
28merchList.add( new Merchandise__c(
29    Name='Pens',
30    Description__c='Blue pens',
31    Price__c=1.75,
32    Total_Inventory__c=800));
33System.debug(merchList);
34
35merchList.sort();
36System.assertEquals('Notebooks', merchList[0].Name);
37System.assertEquals('Pens', merchList[1].Name);
38System.assertEquals('Blue pens', merchList[1].Description__c);
39System.assertEquals('Pens', merchList[2].Name);
40System.assertEquals('Red pens', merchList[2].Description__c);
41System.debug(merchList);

sObject のカスタム並び替え順

リストを sObject のカスタム並び替え順にするには、sObject のラッパークラスを作成し、Comparable インターフェースを実装します。ラッパークラスに対象の sObject を含め、並び替えロジックを指定する compareTo メソッドを実装します。

次の例では、Opportunity のラッパークラスを作成する方法を示します。このクラスの compareTo メソッドの実装では、Amount 項目 (このインスタンスに含まれるクラスメンバー変数)、およびメソッドに渡された商談オブジェクトに基づいて 2 つの商談を比較します。

1swfobject.registerObject("clippy.codeblock-2", "9");
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17global class OpportunityWrapper implements Comparable {
18
19    public Opportunity oppy;
20    
21    // Constructor
22    public OpportunityWrapper(Opportunity op) {
23        oppy = op;
24    }
25    
26    // Compare opportunities based on the opportunity amount.
27    global Integer compareTo(Object compareTo) {
28        // Cast argument to OpportunityWrapper
29        OpportunityWrapper compareToOppy = (OpportunityWrapper)compareTo;
30        
31        // The return value of 0 indicates that both elements are equal.
32        Integer returnValue = 0;
33        if (oppy.Amount > compareToOppy.oppy.Amount) {
34            // Set return value to a positive value.
35            returnValue = 1;
36        } else if (oppy.Amount < compareToOppy.oppy.Amount) {
37            // Set return value to a negative value.
38            returnValue = -1;
39        }
40        
41        return returnValue;       
42    }
43}

次の例には、OpportunityWrapper クラスのテストが含まれています。OpportunityWrapper オブジェクトのリストを並び替え、リストの要素が商談金額を基準に並び替えられていることを確認します。

1swfobject.registerObject("clippy.codeblock-3", "9");
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17@isTest 
18private class OpportunityWrapperTest {
19    static testmethod void test1() {
20        // Add the opportunity wrapper objects to a list.
21        OpportunityWrapper[] oppyList = new List<OpportunityWrapper>();
22        Date closeDate = Date.today().addDays(10);
23        oppyList.add( new OpportunityWrapper(new Opportunity(
24            Name='Edge Installation',
25            CloseDate=closeDate,
26            StageName='Prospecting',
27            Amount=50000)));
28        oppyList.add( new OpportunityWrapper(new Opportunity(
29            Name='United Oil Installations',
30            CloseDate=closeDate,
31            StageName='Needs Analysis',
32            Amount=100000)));
33        oppyList.add( new OpportunityWrapper(new Opportunity(
34            Name='Grand Hotels SLA',
35            CloseDate=closeDate,
36            StageName='Prospecting',
37            Amount=25000)));
38        
39        // Sort the wrapper objects using the implementation of the 
40        // compareTo method.
41        oppyList.sort();
42        
43        // Verify the sort order
44        System.assertEquals('Grand Hotels SLA', oppyList[0].oppy.Name);
45        System.assertEquals(25000, oppyList[0].oppy.Amount);
46        System.assertEquals('Edge Installation', oppyList[1].oppy.Name);
47        System.assertEquals(50000, oppyList[1].oppy.Amount);
48        System.assertEquals('United Oil Installations', oppyList[2].oppy.Name);
49        System.assertEquals(100000, oppyList[2].oppy.Amount);
50        
51        // Write the sorted list contents to the debug log.
52        System.debug(oppyList);
53    }
54}

Force.com Apex コード開発者ガイド

sObject のリストの並び替え

sObject のデフォルトの並び替え順

sObject のカスタム並び替え順