Apex からの PDF としての Visualforce ページの表示

1public with sharing class PdfEmailerController {
2    
3    // Form fields
4    public Id selectedAccount    { get; set; }  // Account selected on Visualforce page
5    public String selectedReport { get; set; }  // Report selected
6    public String recipientEmail { get; set; }  // Send to this email
7    
8    // Action method for the [Send Account Summary] button
9    public PageReference sendReport() {
10
11        // NOTE: Abbreviated error checking to keep the code sample short
12        //       You, of course, would never do this little error checking
13        if(String.isBlank(this.selectedAccount) || String.isBlank(this.recipientEmail)) {
14            ApexPages.addMessage(new 
15                ApexPages.Message(ApexPages.Severity.ERROR, 
16               'Errors on the form. Please correct and resubmit.'));
17            return null; // early out
18        }
19        
20        // Get account name for email message strings
21        Account account = [SELECT Name 
22                           FROM Account 
23                           WHERE Id = :this.selectedAccount 
24                           LIMIT 1];
25        if(null == account) {
26            // Got a bogus ID from the form submission
27            ApexPages.addMessage(new 
28                ApexPages.Message(ApexPages.Severity.ERROR, 
29               'Invalid account. Please correct and resubmit.'));
30            return null; // early out
31        }
32        
33        // Create email
34        Messaging.SingleEmailMessage message = new Messaging.SingleEmailMessage();
35        message.setToAddresses(new String[]{ this.recipientEmail });
36        message.setSubject('Account summary for ' + account.Name);
37        message.setHtmlBody('Here\'s a summary for the ' + account.Name + ' account.');
38        
39        // Create PDF
40        PageReference reportPage = 
41            (PageReference)this.reportPagesIndex.get(this.selectedReport);
42        reportPage.getParameters().put('id', this.selectedAccount);
43        Blob reportPdf;
44        try {
45            reportPdf = reportPage.getContentAsPDF();
46        }
47        catch (Exception e) {
48            reportPdf = Blob.valueOf(e.getMessage());
49        }
50        
51        // Attach PDF to email and send
52        Messaging.EmailFileAttachment attachment = new Messaging.EmailFileAttachment();
53        attachment.setContentType('application/pdf');
54        attachment.setFileName('AccountSummary-' + account.Name + '.pdf');
55        attachment.setInline(false);
56        attachment.setBody(reportPdf);
57        message.setFileAttachments(new Messaging.EmailFileAttachment[]{ attachment });
58        Messaging.sendEmail(new Messaging.SingleEmailMessage[]{ message });
59        
60        ApexPages.addMessage(new 
61            ApexPages.Message(ApexPages.Severity.INFO,
62           'Email sent with PDF attachment to ' + this.recipientEmail));
63
64        return null; // Stay on same page, even on success
65    }
66    
67    
68    /***** Form Helpers *****/
69    
70    // Ten recently-touched accounts, for the Account selection menu
71    public List<SelectOption> recentAccounts {
72        get {
73            if(null == recentAccounts){
74                recentAccounts = new List<SelectOption>();
75                for(Account acct : [SELECT Id,Name,LastModifiedDate 
76                                    FROM Account 
77                                    ORDER BY LastModifiedDate DESC 
78                                    LIMIT 10]) {
79                    recentAccounts.add(new SelectOption(acct.Id, acct.Name));
80                }
81            }
82            return recentAccounts;
83        }
84        set;
85    }
86    
87    // List of available reports, for the Summary Format selection menu
88    public List<SelectOption> reportFormats {
89        get {
90            if(null == reportFormats) {
91                reportFormats = new List<SelectOption>();
92                for(Map <String,Object> report : reports) {
93                    reportFormats.add(new SelectOption(
94                        (String)report.get('name'), (String)report.get('label')));
95                }
96            }
97            return reportFormats;
98        }
99        set;
100    }
101
102    
103    /***** Private Helpers *****/
104    
105    // List of report templates to make available
106    // These are just Visualforce pages you might print to PDF
107    private Map<String,PageReference> reportPagesIndex;
108    private List<Map<String,Object>> reports {
109        get {
110            if(null == reports) {
111                reports = new List<Map<String,Object>>();
112                // Add one report to the list of reports
113                Map<String,Object> simpleReport = new Map<String,Object>();
114                simpleReport.put('name',  'simple');
115                simpleReport.put('label', 'Simple');
116                simpleReport.put('page',   Page.ReportAccountSimple);
117                reports.add(simpleReport);
118                
119                // Add your own, more complete list of PDF templates here
120
121                // Index the page names for the reports
122                this.reportPagesIndex = new Map<String,PageReference>();
123                for(Map<String,Object> report : reports) {
124                    this.reportPagesIndex.put(
125                        (String)report.get('name'), (PageReference)report.get('page'));
126                }
127            }
128            return reports;
129        }
130        set;
131    }
132}