Org クラス

1public class OrgCacheController {
2
3    // Inner class.
4    // Used as the data type of a cache value.
5    class MyData {    
6        public String value { get; set; }
7        public Integer counter { get; set; }
8        
9        public MyData(String value) {
10            this.value = value;
11            this.counter = 0;
12        }
13        
14        public void inc() {
15            counter++;
16        }
17        
18        override public String toString() {
19            return this.value + ':' + this.counter;
20        }    
21    }
22    
23    // Apex List.
24    // Used as the data type of a cached value.
25    private List<String> numbers = 
26            new List<String> { 'ONE', 'TWO', 'THREE', 'FOUR', 'FIVE' }; 
27               
28    // Constructor of the controller for the Visualforce page. 
29    public OrgCacheController() {  
30    }
31            
32    // Adds various values to the cache.
33    // This method is called when the Visualforce page loads.
34    public void init() {  
35        // All key values are not qualified by the namespace.partition
36        // prefix because they use the default partition.
37        
38        // Add counter to the cache with initial value of 0
39        //  or increment it if it's already there.
40        if (!Cache.Org.contains('counter')) {
41            Cache.Org.put('counter', 0);
42        } else {
43            Cache.Org.put('counter', getCounter() + 1);
44        }
45              
46        // Add the datetime value to the cache only if it's not already there.
47        if (!Cache.Org.contains('datetime')) {
48            DateTime dt = DateTime.now();
49            Cache.Org.put('datetime', dt);
50        }
51     
52        // Add the custom data to the cache only if it's not already there.
53        if (!Cache.Org.contains('data')) {
54            Cache.Org.put('data', new MyData('Some custom value'));
55        }
56                
57        // Add a list of number to the cache if not already there.
58        if (!Cache.Org.contains('list')) {  
59            Cache.Org.put('list', numbers);
60        }
61                
62        // Add a string value to the cache if not already there.
63        if (!Cache.Org.contains('output')) {
64            Cache.Org.put('output', 'Cached text value');
65        }
66    }
67    
68    // Return counter from the cache.
69    public Integer getCounter() {
70        return (Integer)Cache.Org.get('counter');
71    }
72    
73    // Return datetime value from the cache.
74    public String getCachedDatetime() {
75        DateTime dt = (DateTime)Cache.Org.get('datetime');
76        return dt != null ? dt.format() : null;
77    }
78    
79    // Return cached value whose type is the inner class MyData.
80    public String getCachedData() {
81        MyData mydata = (MyData)Cache.Org.get('data');
82        return mydata != null ? mydata.toString() : null;
83    }
84    
85    // Return output from the cache.
86    public String getOutput() {
87        return (String)Cache.Org.get('output');
88    }
89    
90    // Return list from the cache.
91    public List<String> getList() {
92        return (List<String>)Cache.Org.get('list');
93    }
94    
95    // Method invoked by the Rerender button on the Visualforce page.
96    // Updates the values of various cached values.
97    // Increases the values of counter and the MyData counter if those 
98    //   cache values are still in the cache.
99    public PageReference go() {
100        // Increase the cached counter value or set it to 0 
101        //  if it's not cached.        
102        if (Cache.Org.contains('counter')) {
103            Cache.Org.put('counter', getCounter() + 1);
104        } else {
105            Cache.Org.put('counter', 0);
106        }        
107    
108        // Get the custom data value from the cache.
109        MyData d = (MyData)Cache.Org.get('data');
110        // Only if the data is already in the cache, update it.
111        if (Cache.Org.contains('data')) {
112            d.inc();
113            Cache.Org.put('data', d);            
114        }        
115
116        return null;
117    }
118    
119    // Method invoked by the Remove button on the Visualforce page.
120    // Removes the datetime cached value from the org cache.
121    public PageReference remove() {
122        Cache.Org.remove('datetime');
123
124        return null;
125    }
126}