Apex スケジューラ

Schedulable インターフェースの実装

1global void execute(SchedulableContext sc){}

1global class scheduledMerge implements Schedulable {
2   global void execute(SchedulableContext SC) {
3      mergeNumbers M = new mergeNumbers(); 
4   }
5}

1scheduledMerge m = new scheduledMerge();
2String sch = '20 30 8 10 2 ?';
3String jobID = system.schedule('Merge Job', sch, m);

1global class scheduledBatchable implements Schedulable {
2   global void execute(SchedulableContext sc) {
3      batchable b = new batchable(); 
4      database.executebatch(b);
5   }
6}

クエリを使用したスケジュール済みジョブの進行状況の追跡

Apex ジョブがスケジュールされた後、CronTrigger に対して SOQL クエリを実行して、このジョブの詳細情報を取得することができます。次の例に示すように、ジョブの実行回数と、ジョブの再実行がスケジュールされている日時を取得できます。

1CronTrigger ct = 
2    [SELECT TimesTriggered, NextFireTime
3    FROM CronTrigger WHERE Id = :jobID];

この例では、ユーザがジョブの ID を保持する jobID 変数を使用していることが前提となります。System.schedule メソッドは、ジョブ ID を返します。スケジュール可能なクラスの execute メソッド内でこのクエリを実行すると、SchedulableContext 引数の変数に対して getTriggerId をコールすることで現在のジョブの ID を取得できます。この変数名が sc であるとすると、変更後の例は次のようになります。

1CronTrigger ct = 
2    [SELECT TimesTriggered, NextFireTime
3    FROM CronTrigger WHERE Id = :sc.getTriggerId()];

また、CronTrigger レコードに関連付けられている CronJobDetail レコードからジョブの名前と種別を取得することもできます。そのためには、CronTrigger に対してクエリを実行するときに CronJobDetail リレーションを使用します。次の例では、CronJobDetail にあるジョブの名前と種別を含む最新の CronTrigger レコードを取得します。

1CronTrigger job = 
2    [SELECT Id, CronJobDetail.Id, CronJobDetail.Name, CronJobDetail.JobType 
3    FROM CronTrigger ORDER BY CreatedDate DESC LIMIT 1];

また、CronJobDetail を直接照会して、ジョブの名前と種別を取得することもできます。次の例では、前の例で照会した CronTrigger レコードに対してジョブの名前と種別を取得します。対応する CronJobDetail レコード ID は、CronTrigger レコードの CronJobDetail.Id 式によって取得されます。

1CronJobDetail ctd = 
2    [SELECT Id, Name, JobType 
3    FROM CronJobDetail WHERE Id = :job.CronJobDetail.Id];

他の種別のすべてのスケジュール済みジョブを除く、すべての Apex スケジュール済みジョブの合計件数を取得するには、次のクエリを実行します。ジョブ種別には「7」という値が指定されています。これは、Apex スケジュール済みジョブの種別に対応します。

1SELECT COUNT() FROM CronTrigger WHERE CronJobDetail.JobType = '7'

Apex スケジューラのテスト

1global class TestScheduledApexFromTestMethod implements Schedulable {
2
3// This test runs a scheduled job at midnight Sept. 3rd. 2022
4
5   public static String CRON_EXP = '0 0 0 3 9 ? 2022';
6   
7   global void execute(SchedulableContext ctx) {
8      CronTrigger ct = [SELECT Id, CronExpression, TimesTriggered, NextFireTime
9                FROM CronTrigger WHERE Id = :ctx.getTriggerId()];
10
11      System.assertEquals(CRON_EXP, ct.CronExpression);
12      System.assertEquals(0, ct.TimesTriggered);
13      System.assertEquals('2022-09-03 00:00:00', String.valueOf(ct.NextFireTime));
14
15      Account a = [SELECT Id, Name FROM Account WHERE Name = 
16                  'testScheduledApexFromTestMethod'];
17      a.name = 'testScheduledApexFromTestMethodUpdated';
18      update a;
19   }   
20}

1@istest
2class TestClass {
3
4   static testmethod void test() {
5   Test.startTest();
6
7      Account a = new Account();
8      a.Name = 'testScheduledApexFromTestMethod';
9      insert a;
10
11      // Schedule the test job
12
13      String jobId = System.schedule('testBasicScheduledApex',
14      TestScheduledApexFromTestMethod.CRON_EXP, 
15         new TestScheduledApexFromTestMethod());
16
17      // Get the information from the CronTrigger API object
18      CronTrigger ct = [SELECT Id, CronExpression, TimesTriggered, 
19         NextFireTime
20         FROM CronTrigger WHERE id = :jobId];
21
22      // Verify the expressions are the same
23      System.assertEquals(TestScheduledApexFromTestMethod.CRON_EXP, 
24         ct.CronExpression);
25
26      // Verify the job has not run
27      System.assertEquals(0, ct.TimesTriggered);
28
29      // Verify the next time the job will run
30      System.assertEquals('2022-09-03 00:00:00', 
31         String.valueOf(ct.NextFireTime));
32      System.assertNotEquals('testScheduledApexFromTestMethodUpdated',
33         [SELECT id, name FROM account WHERE id = :a.id].name);
34
35   Test.stopTest();
36
37   System.assertEquals('testScheduledApexFromTestMethodUpdated',
38   [SELECT Id, Name FROM Account WHERE Id = :a.Id].Name);
39
40   }
41}

System.Schedule メソッドの使用

1Seconds Minutes Hours Day_of_month Month Day_of_week Optional_year

式の値は次のとおりです。

次に、式の使用方法の例を示します。

次の例では、クラス proschedule によって Schedulable インターフェースが実装されます。このクラスは、2 月 13 日の午前 8 時に実行するようにスケジュールされています。

1proschedule p = new proschedule();
2        String sch = '0 0 8 13 2 ?';
3        system.schedule('One Time Pro', sch, p);

System.scheduleBatch メソッドを使用した一括処理ジョブの実行

System.scheduleBatch メソッドをコールして、将来の指定された時刻に 1 回実行されるように一括処理ジョブをスケジュールできます。このメソッドは一括処理クラスにのみ使用できます。また、Schedulable インターフェースを実装する必要はありません。したがって、一括処理ジョブが 1 回実行されるように簡単にスケジュール設定できます。System.scheduleBatch メソッドの使用方法についての詳細は、「System.scheduleBatch メソッドの使用」を参照してください。

Apex スケジューラの制限

• 一度にスケジュールできる Apex ジョブの数は 100 です。現在の数を確認するには、Salesforce の [スケジュール済みジョブ] ページを表示し、データ型の検索条件を [スケジュール済み Apex] にしてカスタムビューを作成します。また、CronTrigger オブジェクトおよび CronJobDetail オブジェクトをプログラムで照会することで、Apex スケジュール済みジョブの数を取得することもできます。

• 24 時間でのスケジュール済み Apex の最大実行数は、250,000 または組織のライセンス数の 200 倍の大きい方です。これは組織全体の制限で、他のすべての非同期 Apex (Apex 一括処理、キュー可能 Apex、スケジュール済み Apex、および future メソッド) と共有されます。使用可能な非同期 Apex 実行の数を確認するには、REST API limits リソースに対して要求を実行します。『REST API 開発者ガイド』の「組織の制限をリストする」を参照してください。この制限に反映されるライセンスの種類は、Salesforce フルユーザライセンス、Salesforce Platform ユーザライセンス、アプリケーションサブスクリプションのユーザライセンス、Chatter Only ユーザ、Identity ユーザ、Company Community ユーザです。

Apex スケジューラの注意点とベストプラクティス

• Salesforce は、指定された時間に実行されるようにクラスをスケジュール設定します。実際の実行は、サービスの使用可能状態に応じて遅れる場合があります。
• クラスをトリガからスケジュールする場合は、細心の注意を払ってください。制限を超えるスケジュールクラスをトリガで追加しないようにする必要があります。特に、API の一括更新、インポートウィザード、ユーザインターフェースを使用したレコードの一括変更、および複数のレコードを一度に更新するすべての処理については十分に考慮してください。
• execute メソッドで追加処理を行うことはできますが、すべての処理が個別のクラスで行われるようにすることをお勧めします。
• 同期 Web サービス���ールアウトは、スケジュールされた Apex からは実行できません。非同期コールアウトを実行するには、Database.AllowsCallouts マーカーインターフェースを実装して、キュー可能 Apex を使用します。スケジュールされた Apex で、Database.AllowsCallouts マーカーインターフェースを使用して一括処理ジョブを実行する場合、一括処理クラスからコールアウトを実行できます。「Apex の一括処理の使用」を参照してください。
• Salesforce のサービスメンテナンスによるダウンタイム中に実行がスケジュールされている Apex ジョブは、サービスが再開され、システムリソースが使用可能になったときに実行されるようにスケジュールされます。ダウンタイムの発生時にスケジュール済みの Apex ジョブが実行されていた場合は、ジョブがロールバックされ、サービス再開後に再度スケジュールされます。サービスのメジャーアップグレードの後は、システムの使用率が急増するため、スケジュール済みの Apex ジョブの開始が通常より遅れる可能性があります。
• スケジュール済みジョブオブジェクトとそのメンバー変数およびプロパティは、初期化から後続のスケジュールされた実行まで存続します。System.schedule() を呼び出した時点のオブジェクトの状態は、後続のジョブ実行時にも存続しています。

  Apex の一括処理では、Database.stateful を使用して、新しいジョブに新しいシリアライズされた状態を強制することができます。スケジュール済みの Apex では、transient キーワードを使用して、メンバー変数とプロパティが存続しないようにします。「transient キーワードの使用」を参照してください。